cmake_minimum_required(VERSION 3.22)
project(moveit_setup_srdf_plugins LANGUAGES CXX)

# Common cmake code applied to all moveit packages
find_package(moveit_common REQUIRED)
moveit_package()

find_package(ament_cmake REQUIRED)
find_package(ament_cmake_ros REQUIRED)
# rviz switched to Qt6 in 15.1.14: https://github.com/ros2/rviz/pull/1635
# (merged 2025-12-08, first released in the 15.1.14 tag on 2025-12-17 -- 15.1.0
# through 15.1.13 are still Qt5)
find_package(rviz2 QUIET)
if(rviz2_VERSION VERSION_GREATER_EQUAL 15.1.14)
  find_package(Qt6 REQUIRED COMPONENTS Core Widgets)
  set(QT_VERSION_MAJOR 6)
  # Hint for transitive deps that use find_package(QT NAMES Qt6 Qt5 ...) which
  # may incorrectly resolve to Qt5 due to CMake's ascending path order
  set(QT_DIR "${Qt6_DIR}")
else()
  find_package(Qt5 REQUIRED COMPONENTS Core Widgets)
  set(QT_VERSION_MAJOR 5)
endif()
find_package(moveit_setup_framework REQUIRED)
find_package(pluginlib REQUIRED)

set(CMAKE_AUTOMOC ON)

add_library(
  moveit_setup_srdf_plugins
  src/collision_linear_model.cpp
  src/collision_matrix_model.cpp
  src/compute_default_collisions.cpp
  src/default_collisions.cpp
  src/default_collisions_widget.cpp
  src/end_effectors.cpp
  src/end_effectors_widget.cpp
  src/group_edit_widget.cpp
  src/group_meta_config.cpp
  src/kinematic_chain_widget.cpp
  src/passive_joints.cpp
  src/passive_joints_widget.cpp
  src/planning_groups.cpp
  src/planning_groups_widget.cpp
  src/robot_poses.cpp
  src/robot_poses_widget.cpp
  src/rotated_header_view.cpp
  src/virtual_joints.cpp
  src/virtual_joints_widget.cpp
  include/moveit_setup_srdf_plugins/collision_linear_model.hpp
  include/moveit_setup_srdf_plugins/collision_matrix_model.hpp
  include/moveit_setup_srdf_plugins/default_collisions_widget.hpp
  include/moveit_setup_srdf_plugins/end_effectors_widget.hpp
  include/moveit_setup_srdf_plugins/group_edit_widget.hpp
  include/moveit_setup_srdf_plugins/kinematic_chain_widget.hpp
  include/moveit_setup_srdf_plugins/passive_joints_widget.hpp
  include/moveit_setup_srdf_plugins/planning_groups_widget.hpp
  include/moveit_setup_srdf_plugins/robot_poses_widget.hpp
  include/moveit_setup_srdf_plugins/rotated_header_view.hpp
  include/moveit_setup_srdf_plugins/virtual_joints_widget.hpp)
target_include_directories(
  moveit_setup_srdf_plugins
  PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
         $<INSTALL_INTERFACE:include/moveit_setup_srdf_plugins>)
target_link_libraries(
  moveit_setup_srdf_plugins moveit_setup_framework::moveit_setup_framework
  pluginlib::pluginlib)

if(BUILD_TESTING)
  find_package(ament_cmake_gtest REQUIRED)
  ament_add_gtest(test_srdf test/test_srdf.cpp)
  target_link_libraries(test_srdf moveit_setup_srdf_plugins)
endif()

install(
  TARGETS moveit_setup_srdf_plugins
  EXPORT moveit_setup_srdf_pluginsTargets
  ARCHIVE DESTINATION lib
  LIBRARY DESTINATION lib
  RUNTIME DESTINATION bin
  INCLUDES
  DESTINATION include/moveit_setup_srdf_plugins)
install(FILES moveit_setup_framework_plugins.xml
        DESTINATION share/moveit_setup_srdf_plugins)
install(DIRECTORY include/ DESTINATION include/moveit_setup_srdf_plugins)

ament_export_targets(moveit_setup_srdf_pluginsTargets HAS_LIBRARY_TARGET)
pluginlib_export_plugin_description_file(moveit_setup_framework
                                         moveit_setup_framework_plugins.xml)

ament_package()
