cmake_minimum_required(VERSION 3.20)
project(point_cloud_transport_py)

# The C++/C standard comes from ament_ros_defaults (cxx_std_20 / c_std_17),
# provided by the ament_cmake_ros_core::ament_ros_defaults INTERFACE target and
# linked PRIVATE into the Python extension modules below. They are not consumed
# as C++ targets, so the standard does not need to propagate anywhere.
if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  add_compile_options(-Wall -Wextra -Wpedantic)
endif()

find_package(ament_cmake REQUIRED)
find_package(ament_cmake_ros_core REQUIRED)
find_package(ament_cmake_python REQUIRED)
find_package(ament_cmake_ros REQUIRED)
find_package(point_cloud_transport REQUIRED)
find_package(pluginlib REQUIRED)
find_package(rclcpp REQUIRED)
find_package(sensor_msgs REQUIRED)

# By default, without the settings below, find_package(Python3) will attempt
# to find the newest python version it can, and additionally will find the
# most specific version.  For instance, on a system that has
# /usr/bin/python3.10, /usr/bin/python3.11, and /usr/bin/python3, it will find
# /usr/bin/python3.11, even if /usr/bin/python3 points to /usr/bin/python3.10.
# The behavior we want is to prefer the "system" installed version unless the
# user specifically tells us othewise through the Python3_EXECUTABLE hint.
# Setting CMP0094 to NEW means that the search will stop after the first
# python version is found.  Setting Python3_FIND_UNVERSIONED_NAMES means that
# the search will prefer /usr/bin/python3 over /usr/bin/python3.11.  And that
# latter functionality is only available in CMake 3.20 or later, so we need
# at least that version.
cmake_policy(SET CMP0094 NEW)
set(Python3_FIND_UNVERSIONED_NAMES FIRST)

# Find python before pybind11
find_package(Python3 REQUIRED COMPONENTS Interpreter Development)

find_package(pybind11 REQUIRED)

ament_python_install_package(${PROJECT_NAME})

pybind11_add_module(_point_cloud_transport SHARED
  src/point_cloud_transport_py/pybind_point_cloud_transport.cpp
)
target_link_libraries(_point_cloud_transport PUBLIC
  point_cloud_transport::point_cloud_transport
  rclcpp::rclcpp
  sensor_msgs::sensor_msgs
)
target_link_libraries(_point_cloud_transport PRIVATE
  ament_cmake_ros_core::ament_ros_defaults
)

pybind11_add_module(_codec SHARED
  src/point_cloud_transport_py/pybind_codec.cpp
)
target_link_libraries(_codec PUBLIC
  point_cloud_transport::point_cloud_transport
  pluginlib::pluginlib
)
target_link_libraries(_codec PRIVATE
  ament_cmake_ros_core::ament_ros_defaults
)

# Install cython modules as sub-modules of the project
install(
  TARGETS
    _point_cloud_transport
    _codec
  DESTINATION "${PYTHON_INSTALL_DIR}/${PROJECT_NAME}"
)

if(BUILD_TESTING)
  find_package(ament_lint_auto REQUIRED)

  ament_lint_auto_find_test_dependencies()
endif()

ament_package()
