# MIT License
#
# Copyright (c) 2025 Meher V.R. Malladi.
#
# Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated
# documentation files (the "Software"), to deal in the Software without restriction, including without limitation the
# rights to use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of the Software, and to permit
# persons to whom the Software is furnished to do so, subject to the following conditions:
#
# The above copyright notice and this permission notice shall be included in all copies or substantial portions of the
# Software.
#
# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE
# WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR
# COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR
# OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

cmake_minimum_required(VERSION 3.22.0)
project(rko_lio LANGUAGES CXX C)

if(POLICY CMP0135)
  cmake_policy(SET CMP0135 NEW)
endif()

option(RKO_LIO_BUILD_ROS "Build the ROS wrapper for RKO LIO" ON)
option(RKO_LIO_BUILD_TESTS "Build core C++ tests" OFF)
option(RKO_LIO_FETCH_CONTENT_DEPS "Fetch dependencies via FetchContent instead of using find_package" OFF)

include(cmake/dependencies.cmake)
include(cmake/compat_target_sources.cmake)

find_package(Eigen3 3.4 REQUIRED CONFIG)
find_package(Sophus REQUIRED CONFIG)
find_package(TBB REQUIRED CONFIG)
find_package(tsl-robin-map REQUIRED CONFIG)
find_package(spdlog REQUIRED CONFIG)

add_subdirectory(rko_lio/core)

if(NOT RKO_LIO_BUILD_ROS)
  message(STATUS "RKO_LIO_BUILD_ROS is OFF. Skipping ROS Build.")
else()
  message(STATUS "Building RKO_LIO ROS wrapper.")

  find_package(ament_cmake REQUIRED)
  find_package(rclcpp REQUIRED CONFIG)
  find_package(std_msgs REQUIRED CONFIG)
  find_package(tf2 REQUIRED CONFIG)
  find_package(tf2_ros REQUIRED CONFIG)
  find_package(sensor_msgs REQUIRED CONFIG)
  find_package(nav_msgs REQUIRED CONFIG)
  find_package(geometry_msgs REQUIRED CONFIG)
  find_package(rosbag2_cpp REQUIRED CONFIG)
  find_package(rosbag2_storage REQUIRED CONFIG)
  find_package(rclcpp_components REQUIRED CONFIG)
  find_package(point_cloud_transport REQUIRED CONFIG)
  find_package(point_cloud_interfaces REQUIRED CONFIG)

  add_subdirectory(rko_lio/ros)

  # ament macros cannot be in a CMake subdirectory, even rclcpp
  rclcpp_components_register_node(
    online_node_component
    PLUGIN
    "rko_lio::ros::OnlineNode"
    EXECUTABLE
    online_node)

  rclcpp_components_register_node(
    online_imu_rate_node_component
    PLUGIN
    "rko_lio::ros::OnlineImuRateNode"
    EXECUTABLE
    online_imu_rate_node)

  if(NOT RKO_LIO_FETCH_CONTENT_DEPS AND CMAKE_VERSION VERSION_GREATER_EQUAL "3.23")
    install(
      TARGETS rko_lio.core rko_lio.ros rko_lio.ros.utils
      EXPORT rko_lioTargets
      FILE_SET HEADERS FILE_SET generated_headers)

    ament_export_targets(rko_lioTargets HAS_LIBRARY_TARGET)
    ament_export_dependencies(
      Eigen3
      Sophus
      TBB
      tsl-robin-map
      spdlog
      rclcpp
      std_msgs
      tf2
      tf2_ros
      sensor_msgs
      nav_msgs
      geometry_msgs
      rosbag2_cpp
      rosbag2_storage
      point_cloud_transport
      point_cloud_interfaces)
  endif()

  install(
    TARGETS online_node_component online_imu_rate_node_component offline_node
    LIBRARY DESTINATION lib
    RUNTIME DESTINATION lib/${PROJECT_NAME})

  install(DIRECTORY config launch DESTINATION share/rko_lio)

  ament_package()
endif()

if(RKO_LIO_BUILD_TESTS)
  enable_testing()
  add_subdirectory(tests/core)
endif()
