cmake_minimum_required(VERSION 3.10)
project(robstride_driver)

if(NOT CMAKE_CXX_STANDARD)
  set(CMAKE_CXX_STANDARD 17)
endif()
add_compile_options(-Wall -Wextra -Wpedantic)

find_package(ament_cmake REQUIRED)
find_package(can_msgs REQUIRED)
find_package(diagnostic_msgs REQUIRED)
find_package(rclcpp REQUIRED)
find_package(Threads REQUIRED)

add_library(${PROJECT_NAME} SHARED
  src/can_transport.cpp
  src/driver.cpp
  src/metrics.cpp
  src/motor_profile.cpp
  src/protocol.cpp
)
add_library(${PROJECT_NAME}::${PROJECT_NAME} ALIAS ${PROJECT_NAME})
target_include_directories(${PROJECT_NAME} PUBLIC
  $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
  $<INSTALL_INTERFACE:include>
)
if(COMMAND ament_target_dependencies)
  ament_target_dependencies(${PROJECT_NAME} can_msgs diagnostic_msgs rclcpp)
  target_link_libraries(${PROJECT_NAME} Threads::Threads)
else()
  target_link_libraries(${PROJECT_NAME} PUBLIC
    ${can_msgs_TARGETS}
    ${diagnostic_msgs_TARGETS}
    rclcpp::rclcpp
  )
  target_link_libraries(${PROJECT_NAME} PRIVATE Threads::Threads)
endif()

install(TARGETS ${PROJECT_NAME}
  EXPORT export_${PROJECT_NAME}
  ARCHIVE DESTINATION lib
  LIBRARY DESTINATION lib
  RUNTIME DESTINATION bin
)
install(DIRECTORY include/ DESTINATION include)
install(FILES README.md CHANGELOG.rst LICENSE DESTINATION share/${PROJECT_NAME})

if(BUILD_TESTING)
  find_package(ament_cmake_gtest REQUIRED)
  ament_add_gtest(test_protocol test/test_protocol.cpp)
  target_link_libraries(test_protocol ${PROJECT_NAME})
  ament_add_gtest(test_can_transport test/test_can_transport.cpp)
  target_link_libraries(test_can_transport ${PROJECT_NAME})
  ament_add_gtest(test_joint_data test/test_joint_data.cpp)
  target_link_libraries(test_joint_data ${PROJECT_NAME})
  ament_add_gtest(test_metrics test/test_metrics.cpp)
  target_link_libraries(test_metrics ${PROJECT_NAME})
  if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
    add_library(robstride_vcan_test_support STATIC
      test/support/fake_robstride_motor.cpp
      test/support/vcan_socket.cpp
    )
    target_include_directories(robstride_vcan_test_support PUBLIC test/support)
    target_link_libraries(robstride_vcan_test_support PUBLIC ${PROJECT_NAME} Threads::Threads)

    add_executable(test_vcan_transport_integration test/test_vcan_transport_integration.cpp)
    target_link_libraries(test_vcan_transport_integration robstride_vcan_test_support)
    add_executable(test_vcan_fake_motor_integration test/test_vcan_fake_motor_integration.cpp)
    target_link_libraries(test_vcan_fake_motor_integration robstride_vcan_test_support)
  endif()
endif()

ament_export_include_directories(include)
ament_export_targets(export_${PROJECT_NAME} HAS_LIBRARY_TARGET NAMESPACE ${PROJECT_NAME}::)
ament_export_dependencies(can_msgs diagnostic_msgs rclcpp)
ament_package()
